Marcos Junior

package com.marcosjunior.components.datagrid
{
	import mx.controls.dataGridClasses.DataGridColumn;
	import mx.core.ClassFactory;
 
	public class StylizedDataGridColumn extends DataGridColumn
	{
 
		public function StylizedDataGridColumn()
		{
			super();
			this.itemRenderer = new ClassFactory( StylizedDataGridItemRenderer );
		}
 
		public var stylesFunction:Function
 
	}
 
}

package com.marcosjunior.components.datagrid
{
	import flash.text.TextFormat;
 
	import mx.controls.DataGrid;
	import mx.controls.dataGridClasses.DataGridItemRenderer;
	import mx.controls.dataGridClasses.DataGridListData;
 
	public class StylizedDataGridItemRenderer extends DataGridItemRenderer
	{
		public function StylizedDataGridItemRenderer()
		{
			super();
		}
 
		private var lastUID:String;	
 
		override public function set data(value:Object):void
		{
			super.data = value;
 
			if (listData && listData.uid != lastUID)
			{
				styleChanged("color");
				lastUID = listData.uid;
			}
		}
 
		override public function getTextStyles():TextFormat
		{
			if (!listData) 
			{
				return super.getTextStyles();
			}
 
			var tf:TextFormat = super.getTextStyles();
 
			var dgListData:DataGridListData = listData as DataGridListData;
			var dataGrid:DataGrid = dgListData.owner as DataGrid;
			var column:StylizedDataGridColumn = dataGrid.columns[dgListData.columnIndex];
			var o:Object = column.stylesFunction(data, column);
 
			for (var p:String in o)
			{
				tf[p] = o[p];
			}
 
			return tf;
 
		}
 
 
	}
}

<?xml version="1.0" encoding="utf-8"?>
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" xmlns:datagrid="com.marcosjunior.components.datagrid.*">
 
	<mx:Script>
		<![CDATA[
 
		[Bindable]
		private var _dp:Array = [
			{ aluno: "Marcos Junior", media_final: 9},
			{ aluno: "Fábio Vedovelli", media_final: 9},
			{ aluno: "William Morais", media_final: 7},
			{ aluno: "Tabata Ruiz", media_final: 8},
			{ aluno: "Luiz Augusto", media_final: 5},
			{ aluno: "Camila Rodrigues", media_final: 4},
			{ aluno: "Paulo César", media_final: 4}
			];
 
		private function changeStyles(data:Object, column:DataGridColumn):Object
		{
			var o:Object = new Object();
 
			var value:Number = data[column.dataField];
			if (value < 5)
			{
				o.color = 0xFF0000;
				o.bold = true;
				o.underline = false;
			}
			else if (value < 7)
			{
				o.color = 0xc34805;
				o.bold = false;
				o.underline = true;
			}
			else
			{
				o.color = 0x023064;
				o.bold = false;
				o.underline = false;
			}
			return o;
		}
 
		private function situacao_labelFunction(data:Object, column:DataGridColumn):String
		{
			var value:String = "";
			var media:Number = data["media_final"];
			if (media < 5)
			{
				value = "Reprovado";
			}
			else if (media < 7)
			{
				value = "Exame";
			}
			else
			{
				value = "Aprovado";
			}
			return value;
		}
 
		]]>
	</mx:Script>
 
	<mx:DataGrid id="dg1" dataProvider="{_dp}" top="10" left="10" right="10" bottom="10" verticalAlign="middle" >
		<mx:columns>
		<mx:DataGridColumn headerText="Name" dataField="aluno" width="140"/>
		<mx:DataGridColumn headerText="Média" dataField="media_final" width="60" />
		<datagrid:StylizedDataGridColumn headerText="Situação" dataField="media_final" labelFunction="situacao_labelFunction" stylesFunction="changeStyles" />
		</mx:columns> 
	</mx:DataGrid>
</mx:Application>